Source file may_contain.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
open! Core
module Dependencies = Fix_id.Set

type resolved = private Resolved [@@deriving sexp_of]
type unresolved = private Unresolved [@@deriving sexp_of]

module Single = struct
  type 'resolution t =
    | Yes_or_maybe : 'a t
    | No : 'a t
    | Depends_on_recursion : unresolved t
  [@@deriving sexp_of]

  let merge_resolved (a : resolved t) (b : resolved t) : resolved t =
    match a, b with
    | Yes_or_maybe, Yes_or_maybe -> Yes_or_maybe
    | Yes_or_maybe, No | No, Yes_or_maybe -> Yes_or_maybe
    | No, No -> No
  ;;

  let merge_unresolved (a : unresolved t) (b : unresolved t) : unresolved t =
    match a, b with
    | Yes_or_maybe, Yes_or_maybe -> Yes_or_maybe
    | Yes_or_maybe, Depends_on_recursion | Depends_on_recursion, Yes_or_maybe ->
      Yes_or_maybe
    | Yes_or_maybe, No | No, Yes_or_maybe -> Yes_or_maybe
    | Depends_on_recursion, Depends_on_recursion -> Depends_on_recursion
    | Depends_on_recursion, No | No, Depends_on_recursion -> Depends_on_recursion
    | No, No -> No
  ;;

  let unresolve (a : resolved t) : unresolved t =
    match a with
    | Yes_or_maybe -> Yes_or_maybe
    | No -> No
  ;;

  (* [resolved_equivalent] is only used during resolution of recursive dependencies. We
     map [Depends_on_recursion] to [No] because [No] is the identity for [resolved t] and
     as part of resolution, we'll merge in all of the recursive dependencies. *)
  let resolved_equivalent (a : unresolved t) : resolved t =
    match a with
    | Yes_or_maybe -> Yes_or_maybe
    | No -> No
    | Depends_on_recursion -> No
  ;;
end

type 'resolution t =
  { path : 'resolution Single.t
  ; lifecycle : 'resolution Single.t
  ; input : 'resolution Single.t
  }
[@@deriving sexp_of]

module Resolved = struct
  type nonrec t = resolved t

  let create ~path ~lifecycle ~input = { path; lifecycle; input }

  let merge (a : t) (b : t) =
    { path = Single.merge_resolved a.path b.path
    ; lifecycle = Single.merge_resolved a.lifecycle b.lifecycle
    ; input = Single.merge_resolved a.input b.input
    }
  ;;

  let both_use_path (a : t) (b : t) : bool =
    match a.path, b.path with
    | Yes_or_maybe, Yes_or_maybe -> true
    | Yes_or_maybe, No | No, Yes_or_maybe | No, No -> false
  ;;

  let path contains = contains.path
  let lifecycle contains = contains.lifecycle
  let input contains = contains.input
end

module Unresolved = struct
  type nonrec t =
    { contains : unresolved t
    ; recursive_dependencies : Dependencies.t
    }

  let merge
    { contains = ca; recursive_dependencies = ra }
    { contains = cb; recursive_dependencies = rb }
    =
    { contains =
        { path = Single.merge_unresolved ca.path cb.path
        ; lifecycle = Single.merge_unresolved ca.lifecycle cb.lifecycle
        ; input = Single.merge_unresolved ca.input cb.input
        }
    ; recursive_dependencies = Dependencies.union ra rb
    }
  ;;

  let of_resolved (resolved : Resolved.t) =
    { contains =
        { path = Single.unresolve resolved.path
        ; lifecycle = Single.unresolve resolved.lifecycle
        ; input = Single.unresolve resolved.input
        }
    ; recursive_dependencies = Dependencies.empty
    }
  ;;

  let resolved_equivalent { contains; recursive_dependencies = _ } =
    { path = Single.resolved_equivalent contains.path
    ; lifecycle = Single.resolved_equivalent contains.lifecycle
    ; input = Single.resolved_equivalent contains.input
    }
  ;;

  let lazy_ =
    { contains = { path = Yes_or_maybe; lifecycle = Yes_or_maybe; input = Yes_or_maybe }
    ; recursive_dependencies = Dependencies.empty
    }
  ;;

  let recursive fix_id =
    { contains =
        { path = Depends_on_recursion
        ; lifecycle = Depends_on_recursion
        ; input = Depends_on_recursion
        }
    ; recursive_dependencies = Dependencies.singleton fix_id
    }
  ;;

  let non_recursive
    ~(path : resolved Single.t)
    ~(lifecycle : resolved Single.t)
    ~(input : resolved Single.t)
    =
    { contains =
        { path = Single.unresolve path
        ; lifecycle = Single.unresolve lifecycle
        ; input = Single.unresolve input
        }
    ; recursive_dependencies = Dependencies.empty
    }
  ;;

  let remove_dependency (t : t) ~on:fix_id =
    { t with
      recursive_dependencies = Dependencies.remove t.recursive_dependencies fix_id
    }
  ;;
end