Source file `consistbl.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
(**************************************************************************)
(*                                                                        *)
(*                                 OCaml                                  *)
(*                                                                        *)
(*             Xavier Leroy, projet Cristal, INRIA Rocquencourt           *)
(*                                                                        *)
(*   Copyright 2002 Institut National de Recherche en Informatique et     *)
(*     en Automatique.                                                    *)
(*                                                                        *)
(*   All rights reserved.  This file is distributed under the terms of    *)
(*   the GNU Lesser General Public License version 2.1, with the          *)
(*   special exception on linking described in the file LICENSE.          *)
(*                                                                        *)
(**************************************************************************)

(* Consistency tables: for checking consistency of module CRCs *)

open Misc

module Make (Module_name : sig
  type t
  module Set : Set.S with type elt = t
  module Map : Map.S with type key = t
  module Tbl : Hashtbl.S with type key = t
  val compare : t -> t -> int
end) (Data : sig
  type t
end) = struct
  type t = (Data.t * Digest.t * filepath) Module_name.Tbl.t

  let create () = Module_name.Tbl.create 13

  let clear = Module_name.Tbl.clear

  exception Inconsistency of {
    unit_name : Module_name.t;
    inconsistent_source : string;
    original_source : string;
    inconsistent_data : Data.t;
    original_data : Data.t;
  }

  exception Not_available of Module_name.t

  let check_ tbl name data crc source =
    let (old_data, old_crc, old_source) = Module_name.Tbl.find tbl name in
    if not (Digest.equal crc old_crc)
    then raise(Inconsistency {
        unit_name = name;
        inconsistent_source = source;
        original_source = old_source;
        inconsistent_data = data;
        original_data = old_data;
      })

  let check tbl name data crc source =
    try check_ tbl name data crc source
    with Not_found ->
      Module_name.Tbl.add tbl name (data, crc, source)

  let check_noadd tbl name data crc source =
    try check_ tbl name data crc source
    with Not_found ->
      raise (Not_available name)

  let source tbl name = thd3 (Module_name.Tbl.find tbl name)

  let find t name =
    match Module_name.Tbl.find t name with
    | exception Not_found -> None
    | (data, crc, _) -> Some (data, crc)

  let extract l tbl =
    let l = List.sort_uniq Module_name.compare l in
    List.fold_left (fun assc name -> (name, find tbl name) :: assc) [] l

  let extract_map mod_names tbl =
    Module_name.Set.fold
      (fun name result -> Module_name.Map.add name (find tbl name) result)
      mod_names
      Module_name.Map.empty

  let filter p tbl =
    let to_remove = ref [] in
    Module_name.Tbl.iter
      (fun name _ ->
        if not (p name) then to_remove := name :: !to_remove)
      tbl;
    List.iter
      (fun name ->
         while Module_name.Tbl.mem tbl name do
           Module_name.Tbl.remove tbl name
         done)
      !to_remove
end